第二章 ActionScript 3.0 动画基础Ⅱ[FL 基理译]

核心提示： 从一个影片剪辑中删除一个对象，再把它加载到另一个影片中剪辑中，第二章 ActionScript 3.0 动画基础Ⅱ[FL 基理译](4)，并保持刚刚被删除时的状态，在以前是不可能完成的，一个子对象只能有一个父级，把它加入到另一个父级中，事实上，有时并不需要去删除影片

从一个影片剪辑中删除一个对象，再把它加载到另一个影片中剪辑中，并保持刚刚被删除时的状态，在以前是不可能完成的。事实上，有时并不需要去删除影片，因为，一个子对象只能有一个父级，把它加入到另一个父级中，就会自动从原来的父级中删除。请看下面示例：

package {
　import flash.display.Sprite;
　import flash.events.MouseEvent;
　public class Reparenting extends Sprite {
　 private var parent1:Sprite;
　 private var parent2:Sprite;
　 private var ball:Sprite;
　 public function Reparenting() {
　　 init();
　 }
　 private function init():void {
　　 parent1 = new Sprite();
　　 addChild(parent1);
　　 parent1.graphics.lineStyle(1, 0);
　　 parent1.graphics.drawRect(-50, -50, 100, 100);
　　 parent1.x = 60;
　　 parent1.y = 60;
　　 parent2 = new Sprite();
　　 addChild(parent2);
　　 parent2.graphics.lineStyle(1, 0);
　　 parent2.graphics.drawRect(-50, -50, 100, 100);
　　 parent2.x = 170;
　　 parent2.y = 60;
　　 ball = new Sprite();
　　 parent1.addChild(ball);
　　 ball.graphics.beginFill(0xff0000);
　　 ball.graphics.drawCircle(0, 0, 40);
　　 ball.graphics.endFill();
　　 ball.addEventListener(MouseEvent.CLICK, onBallClick);
　 }
　 public function onBallClick(event:MouseEvent):void {
　　 parent2.addChild(ball);
　 }
　}
}