Flash加载外部文件创建进度条3种方法

核心提示：加载外部文件的进度条（看帮助文档整理），只适合那些不愿看帮助文档的新手，Flash加载外部文件创建进度条3种方法，我只不过加了一些注释，为加载图像文件或 SWF 文件创建进度条创建一个名为 loadImage.fla 的新 Flash 文档，从而更改文档的尺寸，在时间轴中选择第 1 帧，选择"修改"

加载外部文件的进度条（看帮助文档整理），只适合那些不愿看帮助文档的新手。我只不过加了一些注释。

为加载图像文件或 SWF 文件创建进度条

创建一个名为 loadImage.fla 的新 Flash 文档。

选择"修改">"文档"，在宽度文本框中键入 700，在高度文本框中键入 500，从而更改文档的尺寸。

在时间轴中选择第 1 帧，然后在"动作"面板中键入下面的代码：

// 创建剪辑来承载您的内容
this.createEmptyMovieClip("progressBar_mc", 0);
progressBar_mc.createEmptyMovieClip("bar_mc", 1);
progressBar_mc.createEmptyMovieClip("stroke_mc", 2);
// 创建进度框
with (progressBar_mc.stroke_mc) {
　 lineStyle(0, 0x000000);
　 moveTo(0, 0);
　 lineTo(100, 0);
　 lineTo(100, 10);
　 lineTo(0, 10);
　 lineTo(0, 0);
}
//创建进度条
with (progressBar_mc.bar_mc) {
　 beginFill(0xFF0000, 100);
　 moveTo(0, 0);
　 lineTo(100, 0);
　 lineTo(100, 10);
　 lineTo(0, 10);
　 lineTo(0, 0);
　 endFill();
　 _xscale = 0;
}
//进度坐标
progressBar_mc._x = 2;
progressBar_mc._y = 2;
//加载进度
var mclListener:Object = new Object();
//开始加载时进度条缩放为0
mclListener.onLoadStart = function(target_mc:MovieClip) {
　 progressBar_mc.bar_mc._xscale = 0;
};
//在加载过程中进度条进行缩放
mclListener.onLoadProgress = function(target_mc:MovieClip, bytesLoaded:Number, bytesTotal:Number) {
　 progressBar_mc.bar_mc._xscale = Math.round(bytesLoaded/bytesTotal*100);
};
//加载完成后进度移除
mclListener.onLoadComplete = function(target_mc:MovieClip) {
　 progressBar_mc.removeMovieClip();
};
//当执行加载的剪辑的第一帧上的动作时调用（这里设置加载的外部文件的宽高设置）
mclListener.onLoadInit = function(target_mc:MovieClip) {
　 target_mc._height = 500;
　 target_mc._width = 700;
};
// 创建一个剪辑来承载图像。
this.createEmptyMovieClip("image_mc", 100);
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("http://www.helpexamples.com/flash/images/gallery1/images/pic3.jpg", image_mc);