如何检测CPU的主频

　2007-01-13 20:13:55　来源：WEB开发网　闂傚倸鍊搁崐鎼佸磹妞嬪孩顐芥慨姗嗗厳缂傛氨鎲稿鍫罕闂備礁婀遍搹搴ㄥ窗閺嶎偆涓嶆い鏍仦閻撱儵鏌ｉ弴鐐测偓鍦偓姘炬嫹

闂傚倸鍊搁崐鎼佸磹妞嬪海鐭嗗〒姘ｅ亾妤犵偛顦甸弫鎾绘偐閹绘帞鈧參姊哄Ч鍥х仼闁诲繑鑹鹃悾鐑藉蓟閵夛妇鍘甸梺瑙勵問閸犳牠銆傛總鍛婄厱閹艰揪绱曟牎闂侀潧娲ょ€氫即鐛幒妤€绠ｆ繝闈涘暙娴滈箖鏌ｉ姀鈶跺湱澹曟繝姘厵闁绘劦鍓氶悘杈ㄤ繆閹绘帞澧涚紒缁樼洴瀹曞崬螖閸愬啠鍓濈换娑樼暆婵犱胶鏁栫紓浣介哺閹瑰洤鐣烽幒鎴僵闁瑰吀鐒﹂悗鎼佹⒒娴ｇ儤鍤€闁搞倖鐗犻獮蹇涙晸閿燂拷

濠电姷鏁告慨鐑藉极閸涘﹥鍙忔い鎾卞灩缁狀垶鏌涢幇闈涙灈鐎瑰憡绻冮妵鍕箻鐎靛摜鐣奸梺纭咁潐濞茬喎顫忕紒妯肩懝闁逞屽墮宀ｈ儻顦查悡銈夋煏閸繃鍋繛宸簻鎯熼梺瀹犳〃閼冲爼宕濋敃鈧—鍐Χ閸℃鐟愰梺鐓庡暱閻栧ジ宕烘繝鍥у嵆闁靛骏绱曢崢顏堟⒑閹肩偛鍔楅柡鍛⊕缁傛帟顦寸紒杈ㄥ笚濞煎繘鍩℃担閿嬵潟闂備浇妗ㄩ悞锕傚箲閸ヮ剙鏋侀柟鍓х帛閺呮悂鏌ㄩ悤鍌涘闂傚倸鍊搁崐鎼佸磹妞嬪孩顐芥慨姗嗗厳缂傛氨鎲稿鍫罕闂備礁婀遍搹搴ㄥ窗閺嶎偆涓嶆い鏍仦閻撱儵鏌ｉ弴鐐测偓鍦偓姘炬嫹　　闂傚倸鍊搁崐鎼佸磹閻戣姤鍤勯柤鍝ユ暩娴犳氨绱撻崒娆掑厡缂侇噮鍨堕妴鍐川閺夋垹鍘洪悗骞垮劚椤︻垶宕￠幎鑺ョ厪闊洦娲栨牎闂佽瀵掗崜鐔奉潖閾忓湱纾兼俊顖氭惈椤矂姊虹拠鑼婵ǜ鍔戦崺鈧い鎺嶇閸ゎ剟鏌涢幘璺烘瀻妞ゎ偄绻愮叅妞ゅ繐瀚悗顓烆渻閵堝棙绀€闁瑰啿閰ｅ畷婊勫鐎涙ǚ鎷洪梻渚囧亞閸嬫盯鎳熼娑欐珷妞ゆ柨澧界壕鐓庮熆鐠虹尨鍔熺紒澶庢閳ь剚顔栭崰鏍€﹂柨瀣╃箚婵繂鐭堝Σ鐑芥⒑缁嬫鍎愰柟鐟版搐铻為柛鎰╁妷濡插牊绻涢崱妤冪婵炲牊锕㈠缁樻媴妞嬪簼瑕嗙紓鍌氱М閸嬫挻绻涚€涙ḿ鐭ら柛鎾跺枛瀹曟椽鍩€椤掍降浜滈柟鐑樺灥閳ь剙缍婂鎶筋敆閸曨剛鍘遍柣搴秵娴滅兘鐓鍌楀亾鐟欏嫭纾婚柛妤€鍟块锝夊磹閻曚焦鞋闂備礁鎼Λ瀵哥不閹捐钃熼柕濞炬櫆閸嬪棝鏌涚仦鍓р槈妞ゅ骏鎷�

核心提示：概述：说到检测CPU的速度，一般是测试在单位时间内运算的指令条数，如何检测CPU的主频，但用这种方法有太大的局限性，由于受到很多因素的影响，然后除以时间差即可，这里是本文中的所有的源程序，准确度比较低，特别是在Windows环境下

概述：

说到检测CPU的速度，一般是测试在单位时间内运算的指令条数，但用这种方法有太大的局限性，由于受到很多因素的影响，准确度比较低，特别是在Windows环境下，你不知道在你的程序外别的程序占用了多少的时间片。其实，在586及以上档次处理器中，已经有了一条专用的指令来测试主频，那就是 RDTSC指令，意思是读取时间标记计数器(Read Time-Stamp Counter)，Time-stamp counter 是处理器内部的一个64位的MSR (model specific register)，它每个时钟增加一个记数。在处理器复位的时候，初始值为0，RDTSC 指令把 TSC的值低32位装入EAX中，高32位装入EDX中。如果CPU的主频是200MHz，那么在一秒钟内，TSC的值增加 200,000,000 次。所以在计算的时候，把两次的TSC差值除以两次的时间差值就是CPU的主频。

程序的结构如下：初始化的时候设置一个定时器，定时时间为1秒，然后在定时器消息中利用 RDTSC 取得 TSC计数，再和上次保留的值相减，然后除以时间差即可。

这里是本文中的所有的源程序。

源程序：

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;　　Programmed by 罗云彬, bigluo@telekbird.com.cn
;　　Website: http://asm.yeah.net
;　　LuoYunBin's Win32 ASM page (罗云彬的编程乐园)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;　　版本信息
;　　CPU 频率 - 利用586指令 rdtsc 计算CPU的频率
;　　　 V1.0 ------　　2000年6月21日
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
　　　　.586
　　　　.model flat, stdcall
　　　　option casemap :none　 ; case sensitive
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;　　Include 数据
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include　　　　windows.inc
include　　　　user32.inc
include　　　　kernel32.inc
include　　　　comctl32.inc
include　　　　comdlg32.inc
includelib　　user32.lib
includelib　　kernel32.lib
includelib　　comctl32.lib
includelib　　comdlg32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;　　Equ 数据
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DLG_MAIN　　equ　　　　1000
ID_SPEED　　equ　　　　1001
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;　　数据段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
　　　　.data?
dwTickCount　　dd　　?
dwTSC　　　　dd　　?,?
hInstance　　dd　　?
szBuffer　　db　　256 dup　　(?)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;　　子程序声明
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_ProcDlgMain　　PROTO　　:DWORD,:DWORD,:DWORD,:DWORD
　　　　.data
szSpeed　　　　db　　"你的CPU主频为 %d MHz",0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;　　代码段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
　　　　.code
include　　　　Win.asm
;********************************************************************
_ProcDlgMain　　proc　　uses ebx edi esi,
　　　　hWnd:DWORD,wMsg:DWORD,wParam:DWORD,lParam:DWORD
　　　　local　　@stPoint:POINT
　　　　local　　@hWindow
　　　　mov　　eax,wMsg
　　　　.if　　eax == WM_CLOSE
　　　　　　invoke　　EndDialog,hWnd,NULL
　　　　　　invoke　　KillTimer,hWnd,1
　　　　.elseif　　eax == WM_INITDIALOG
　　　　　　invoke　　_CenterWindow,hWnd
　　　　　　invoke　　GetTickCount　　　　;TSC 初始值
　　　　　　mov　　dwTickCount,eax
　　　　　　rdtsc
　　　　　　mov　　dwTSC,eax
　　　　　　mov　　dwTSC+4,edx
　　　　　　invoke　　SetTimer,hWnd,1,1000,NULL
　　　　.elseif　　eax == WM_TIMER
　　　　　　invoke　　GetTickCount
　　　　　　push　　eax
　　　　　　sub　　eax,dwTickCount
　　　　　　pop　　dwTickCount
　　　　　　push　　eax
　　　　　　rdtsc
　　　　　　push　　edx
　　　　　　push　　eax
　　　　　　sub　　eax,dwTSC
　　　　　　sbb　　edx,dwTSC+4
　　　　　　pop　　dwTSC
　　　　　　pop　　dwTSC+4
　　　　　　mov　　ecx,1000000
　　　　　　div　　ecx　　　　　　;除以1Mhz=1000000hz
　　　　　　.if　　edx >= 500000h　　　　;四舍五入
　　　　　　　　inc　　eax
　　　　　　.endif
　　　　　　mov　　ecx,1000
　　　　　　mul　　ecx　　　　　　;1秒=1000毫秒
　　　　　　pop　　ecx　　　　　　;pop出经过的毫秒数
　　　　　　div　　ecx
　　　　　　invoke　　wsprintf,offset szBuffer,offset szSpeed,eax
　　　　　　invoke　　SendDlgItemMessage,hWnd,ID_SPEED,
　　　　　　　　WM_SETTEXT,0,offset szBuffer
　　　　.else
;********************************************************************
;　　注意：对话框的消息处理后，要返回 TRUE,对没有处理的消息
;　　要返回 FALSE
;********************************************************************
　　　　　　mov　　eax,FALSE
　　　　　　ret
　　　　.endif　　　　　
　　　　mov　　eax,TRUE
　　　　ret
　　　　
_ProcDlgMain　　endp
;********************************************************************
start:
　　　　invoke　　GetModuleHandle,NULL
　　　　mov　　hInstance,eax
　　　　invoke　　DialogBoxParam,hInstance,
DLG_MAIN,NULL,offset _ProcDlgMain,0
　　　　invoke　　ExitProcess,NULL
　　　　end　　start