在Asp中如何快速优化分页的技巧

核心提示：foxty [原作] 近日一直在研究如何才能写出高小的分页算法，大概整理了一下，在Asp中如何快速优化分页的技巧，思路如下： 首先数据库里需要有一个自动编号字段（ID），然后第一次访问的时候，不过叶子的算法确实是很不错D，具备通用性，取出所有记录，定制好每页的记录数PageSize

foxty [原作]

　  近日一直在研究如何才能写出高小的分页算法，大概整理了一下，思路如下：
 
　  首先数据库里需要有一个自动编号字段（ID）。然后第一次访问的时候，取出所有记录，定制好每页的记录数PageSize，计算出页数，然后根据页数建立一个一维数组PageId(PageCount)，PageId(0)保存记录初试条件，然后对应每个元素保存每页对应的ID边界码
（
  1，ID边界码：如果数据库记录ID记录序列如下  1，2，3，4，5，6，7，8，9，10，11，12，13，14，15，16
  假设需要按照ID 顺序排序的话 ，PageSize = 5, Pagecount = 4 ，PageId(4)
　 数组PageId的值分别为PageId(0) = 1, PageId(1) = 5 ,PageId(2) = 10,PageId(3) = 15 ,PageId(4) = 16
　 当访问第 i 页的时候就直接找 [PageId(i-1) , PageId(i) ) 之间的记录，这样可以保证每次取的记录都只是PageSize 条记录。
  假设需要按照ID倒序排列的话,
　 数组PageId的值分别为PageId(0) = 16 , PageId(1) = 12 , PageId(2) = 7 ,PageId(3) = 2, PageId(4) = 1, 当访问第 i 页的时候就直接查找ID属于[ PageId(i-1) , PageId(i) ) 

）
 将数组PageId()保存在application()中，以便访问，这样，只是第一次访问分页程序的时候便初始化Application()。代码部分如下:（下面称为新程序）

<%
 Time1 = Timer()
 Dim Conn
 Set Conn = Server.CreateObject("Adodb.Connection")
 Conn.open "Driver={MicroSoft access Driver (*.mdb)};Dbq="&Server.MapPath("db.mdb")
 'www.cncms.com
 Dim Page,PageCounts,PageId,PageList
 Dim Rs,Sql
 Dim IsInit,i
 
 IsInit　 = False　　　　　　　　　　　　　　　　　　　　 '标志为，用来判断Application("PageId")是否初始化
 PageList = 20　　　　　　　　　　　　　　　　　　　　　  '设置每页显示20条数据
 Set Rs　  = Server.CreateObject("Adodb.Recordset")
 Page　　 = Request.QueryString("Page")　　　　　　　　　　　　 '注意页码需要检查类型
 
 If IsEmpty(Application("PageId")) Then　　　　　　　 '如果Application("PageId")还未初始化,则先进行初始化
  Response.Write("Init app!<br>")
  Sql　　  = "Select * From test Order By Id Desc"  '假定这里是按照ID倒序排列
  Rs.open Sql,Conn,1,1  '得到记录集对象
 
  If Not (Rs.Eof  or Rs.Bof) Then
　 Rs.PageSize = PageList　　　　　　　　　　　  '设置每页记录数
　 PageCounts  = Rs.PageCount
　 ReDim PageId(PageCounts)　　　　　　　　　　  '重新定义数组PageId
　 For i = 0 To PageCounts　　　　　　　　　　　 '开始给数组 PageId() 赋值　 
　  If Rs.eof Then Exit For
　  PageId(i) = Rs("ID")
　  Rs.Move (PageList)
　 Next
　 Rs.MoveLast
　 PageId(PageCounts) = Rs("ID")
　 Application.Lock()
　 Application("PageId") = PageId
　 Application.UnLock() 
  End If
  Rs.Close
 End If
 IdStart = Clng(Application("PageId")(Page-1))
 IdEnd　 = Clng(Application("PageId")(Page))
 Sql = "Select * from test where id<="&IdStart&" and id>"&IdEnd&" "
 Rs.open Sql,Conn,1,1
 While Not Rs.eof
  Response.Write(rs(0)&"--"&rs(1))
  Rs.MoveNext
 Wend
 Rs.Close 
 Set Rs = Nothing
 Conn.Close
 Set Conn = Nothing
 
 
 For i = 1 To Ubound(Application("PageId"))
  Response.Write("<a href='Test1.asp?Page="&i&"'>"&i&"</a>　")
 Next
 Time2 = Timer()
 
 Response.Write("<br>"&(Time2-Time1)*1000)
 'Application.Contents.Remove("PageId")
%>

传统分页代码如下:（下面称为旧程序）
<%
 Time1 = Timer()
 Dim Conn
 Set Conn = Server.CreateObject("Adodb.Connection")
 Conn.open "Driver={MicroSoft Access Driver (*.mdb)};Dbq="&Server.MapPath("db.mdb")
 
 Dim Page,PageCounts,PageList
 Dim Rs,Sql
 
 PageList = 20
 Page　　 = Request.QueryString( "Page" )
 Set Rs　 = Server.CreateObject("Adodb.Recordset")
 Sql　　  = "Select * from test order by id desc"
 Rs.Open Sql,Conn,1,1
 
 If Page = "" Then Page = 1
 If Not( Rs.eof Or Rs.Bof ) Then
  Rs.PageSize　　 = PageList
  PageCounts　　  = Rs.PageCount
  Rs.AbsolutePage = Page 
 End If
 
 For i = 1 to PageList
  If Rs.eof Then Exit For
  Response.Write(Rs(0)&"-----"&Rs(1)&"<br>")
  Rs.MoveNext
 next
 
 For i = 1 To PageCounts
  Response.Write("<a href='Test.asp?Page="&i&"'>"&i&"</a>　")
 Next
 Time2 = Timer()
 
 Response.Write("<br>"&(Time2-Time1)*1000)
%>
 
　  其实，总体的思想就是，建立一个Application("PageId")全局数组,每个元素都保存页面所区记录的ID区间，比如，Application("PageId")(0) 保存第一个元素的ID，然后Application("PageId")(1)保存下一页的第一个ID…………依次类推，当需要访问第 i 页的时候，就直接查找ID在 [ Application("PageId")(i-1)  , Application("i") ) 里面的记录集，这样，每次只用查找需要的记录数，而不需要每次都把所有记录都查找一遍，但是，这个方法是在第一次访问的时候，即需要创建数组Application("PageId")的时候比较慢一点，当第N次访问的时候 （N>1）速度就快将近10倍，我采用上面2个程序测试：
  1，数据库记录有32000条记录，旧程序访问一页需要500毫秒左右，新程序只是第一次访问的时候达到这个时间，然后每次都只需要55毫秒左右。
  2，将数据增加到64000条记录，旧程序访问一页需要1000毫秒左右，新程序也是第一次访问的时候达到这个似乎件， 后面每次仍然还是保持在55毫秒左右。
  3，将数据增加到128000条记录，旧程序访问一页需要1900毫秒左右，新程序第一次访问需要2300毫秒左右，然后每次访问只需要70毫秒左右。
  这里需要注意的是数据库每改动一次，Application("PageId") 就需要重新赋值!

　  研究心得：（首先谢谢叶子(DVBBS)的心得）尽量不要用自带的分页程序，Rs.RecordCount 很耗资源。依次，估计Rs.PageCount ……也耗资源，而且用Rs.GetRows()效果也很明显提高。
 
　  经过比较，叶子的算法在记录比较靠前的时候速度以及效率是比较高的。但是不太稳定，有时（很少）会从30毫秒左右跳到1-200毫秒。到了后面效率就明显下降到50-80毫秒，越后效率越低。新算法第一次效率比较低下，大约在500毫秒左右，但是比较稳定，后面一般哦度是50毫秒左右，而且随着库的记录数变化，这个速度依然如此。不会有什么变化。下次就把叶子和我的算法结合起来试试，不过叶子的算法确实是很不错D，具备通用性。我这个只能拿来聊聊了。