金额大写转换

因为找不到相关函数，便自己写了一个，是仿Excel 金额转换，不限金额长度。

const
  NumberArray: array[0..9] of string =
　  ('零', '壹','貳','叁','肆','伍','陆','柒','捌','玖');

// 数字转与大写
function GetMoneySwitch(AMoney: string): string;

  // 去除所有分隔符
  PRocedure ClearComma(var AValue: string);
  begin
　  while Pos(',', AValue) > 0 do
　　  Delete(AValue, Pos(',', AValue), 1);
  end;

  // 测试如果为零将不返回值
  function FiltrateValue(const AValue, AStr: string): string;
  var
　  IntValue: Integer;
  begin
　  IntValue:= StrToIntDef(AValue, 0);
　  if IntValue > 0 then Result:= AStr;
  end;

  // 直接将数字翻译成大写
  function Direct(const AValue: string): string;
  var
　  ResultStr: string;
　  iCount: Integer;
  begin
　  for iCount:= 1 to Length(AValue) do
　　  ResultStr:= ResultStr + NumberArray[StrToInt(AValue[iCount])];
　  Result:= ResultStr;
  end;

  // 将四位长度的数字翻译与大写
  function FourBit(const AValue: string): string;
  var
　  i, x, j: Integer;
　  IntValue: Integer;
　  ResultStr: string;
  begin

　  IntValue:= StrToIntDef(AValue, 0);
　  x:= IntValue;

　  i := x div 1000;
　  j := x mod 1000;
　  if i <> 0 then ResultStr:= NumberArray[i] + '仟'
　  else begin
　　  if Length(AValue) > 3 then ResultStr:= '零';
　  end;

　  i := j div 100;
　  j := j mod 100;
　  if i <> 0 then  ResultStr:= ResultStr + NumberArray[i] + '佰'
　  else begin
　　  if (ResultStr <> '') and (Length(AValue) > 2) and
　　　  (Copy(ResultStr, Length(ResultStr)-1, 2) <> '零') then
　　　  ResultStr:= ResultStr + '零';
　  end;

　  i := j div 10;
　  j := j mod 10;
　  if i <> 0 then ResultStr := ResultStr + NumberArray[i] + '拾'
　  else begin
　　  if (ResultStr <> '') and (Length(AValue) > 1) and
　　　  (Copy(ResultStr, Length(ResultStr)-1, 2) <> '零') then
　　　  ResultStr:= ResultStr + '零';
　  end;

　  ResultStr := ResultStr + NumberArray[j];

　  while Copy(ResultStr, Length(ResultStr)-1, 2) = '零' do
　　  Delete(ResultStr, Length(ResultStr)-1, 2);

　  Result := ResultStr;
  end;

var
  IntegerValue: string;　 // 整数部分的值
  KilomegaValue: string;  // 存储大于千兆的数字
  AccountValue: string;　 // 在千兆以内的整数部分
  DecimalValue: string;　 // 存在小数点后的值

  ResultKilomega: string; // 大于千兆并翻译后的大写字符
  ResultAccount: string;  // 在千兆以内的整数部分并翻译后的大写字符
  ResultDecimal: string;  // 小数点后的值并翻译后的大写字符

  FourBitStr: string;　　 // 最大四位值的字符
begin

  // 清除分隔符
  ClearComma(AMoney);

  // 验证字符串是否合法
  try
　  AMoney:= FloatToStr(StrToFloat(AMoney));
  except
　  raise Exception.Create('无效的数值字符串');
  end;

  // 取到小数据点后的值
  // 取出整数部分的值
  if Pos('.', AMoney) > 0 then
  begin
　  DecimalValue:= Copy(AMoney, Pos('.', AMoney) + 1, Length(AMoney));
　  IntegerValue:= Copy(AMoney, 0, Pos('.', AMoney)-1);
　  ResultDecimal:= '.' + Direct(DecimalValue);
  end
  else IntegerValue:= AMoney;

  // 取到大于千兆的数字
  // 取到在千兆以内的整数部分
  if Length(IntegerValue) > 16 then
  begin
　  KilomegaValue:= Copy(IntegerValue, 0, Length(IntegerValue) - 12);
　  AccountValue:= Copy(IntegerValue,
　　  Length(IntegerValue) - 11, Length(IntegerValue));
　  ResultKilomega:= Direct(KilomegaValue) + '兆';
  end
  else AccountValue:= IntegerValue;

  { 翻译在千兆以内的整数部分 }

  // 翻译在兆与仟兆之间的部份
  if Length(AccountValue) > 12 then
  begin
　  FourBitStr:= Copy(AccountValue, 0, Length(AccountValue) - 12);
　  ResultAccount:= ResultAccount +
　　  FourBit(FourBitStr) + FiltrateValue(FourBitStr, '兆');
　  Delete(AccountValue, 1, Length(AccountValue) - 12);
  end;
  // 翻译在亿与仟亿之间的部份
  if Length(AccountValue) >= 8 then
  begin
　  FourBitStr:= Copy(AccountValue, 0, Length(AccountValue) - 8);
　  ResultAccount:= ResultAccount +
　　  FourBit(FourBitStr) + FiltrateValue(FourBitStr, '亿');
　  Delete(AccountValue, 1, Length(AccountValue) - 8);
  end;
  // 翻译在万与仟万之间的部份
  if Length(AccountValue) >= 5 then
  begin
　  FourBitStr:= Copy(AccountValue, 0, Length(AccountValue) - 4);
　  ResultAccount:= ResultAccount +
　　  FourBit(FourBitStr) + FiltrateValue(FourBitStr, '万');
　  Delete(AccountValue, 1, Length(AccountValue) - 4);
  end;
  // 翻译万以下的部份
  if Length(AccountValue) > 0 then
  begin
　  ResultAccount:= ResultAccount +
　　  FourBit(Copy(AccountValue, 0, Length(AccountValue)));
  end;

  // 组合字符串
  Result:= ResultKilomega + ResultAccount + ResultDecimal;
 
end;